======== txf_vz16.def ========

#if 0

	ＴＸＦをＶZエディタから使っちゃうマクロ＋α
	^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
		(C) えんでん (1992-)1994

    このマクロ使用によるトラブルに作者はなんら責任をおいません。

【使用方法】

　ＶZエディタが最初に読み込むＤＥＦファイル(VZ.DEF等）の「* E その他」と
いうところに下の様に書き，エディタ起動時にマクロ（このファイル）を読み込
ませるようにします（よくわからない場合はＶZエディタのマニュアルをご覧く
ださい。ＶZ１．６の場合，vzfl+txf_vz16と書くといいかもしれません(^_^;)）。
　他のマクロとマクロ番号やコマンドキーが重なっていて不都合が出る場合は予
め適当に変更した方がいいかも。

┌──────────────────────────────────┐
│* E その他                                                          │
│                                                                    │
│1     txf_vz16                                                      │
└──────────────────────────────────┘

　なお，ＶZエディタがＶ１．６の場合は[ctrl]+[K] → [M] → [F]などで後か
ら読み込んでもいいと思います（Ｖ１．５の場合は…）。


■ 清書 [ESC]F
-----------------------------
　・フリーソフトのＴＸＦを使って清書します（∴ＴＸＦが必要）。
　・ブロックモードではブロック内のみ処理します。

■ 行頭に＞を挿入 [ESC]K
-----------------------------
　・カーソル行頭に＞を挿入します。
　・ブロックモードではブロック内の全ての行頭に挿入します。
　・ブロックモード以外ではあまり使う意味がありません（笑）
　・パソコン通信における引用処理などに使えます。
　・マクロを書き換えれば＞を他の文字にすることもできます（あたりまえですが）。

■ 行頭の一文字を削除 [ESC]J
-----------------------------
　・カーソル行頭の一文字を削除します。
　・ブロックモードではブロック内の全てに行の一文字目を削除します。
　・ブロックモード以外ではあまり使う意味がありません（笑）
　・行頭の＞などをまとめて削除するのに使えます。
　・行頭がリターンコードの場合はそれを削除しません。

#endif

* M マクロ

80 [ESC]H "【ツールメニュー】"
	!01

81 [ESC]F "TXFﾃｷｽﾄ整形"
	?. #] &s (mr==$80)? {&b(10) &d .}
	&a("ＴＸＦによる整形をします") (r!=1)? {&d .}
	(mb)? >A
	(mr==1)? {#S #m}
	#E "txf -io " #P #m #[
	#L #P #m
	&m("整形直前のﾃｷｽﾄは拡張子BAKで存在") &d .
:A	t=".\",						;←作業用ﾃﾞｨﾚｸﾄﾘ指定
	#S &?(t) "txf__.tmp" #m
	#E "txf -io " &?(t) "txf__.tmp" #m #[
	#y n=wn,
	#O &?(t) "txf__.tmp" #m
	#b #_ #> #k #C &#T(n) #i
	#E "del " &?(t) "txf__.*" #m #[
	&m("^j で整形前のﾌﾞﾛｯｸを復元可能") &d

82 [ESC]K "行頭に＞を挿入"
	&a("行頭に＞を挿入します") (r!=1)? .
	(mb)? >A #11 '＞' .
:A	&s mi[, mi=0, n=ln,
	#B o=ln, #B
	(n<o)? >C >B
:B	#11 '＞' (ln!=o)? {#e >B} mi], #b &d.
:C	#11 '＞' (ln!=o)? {#12 #x >C} mi], #b &d.

83 [ESC]J "行頭の１文字を削除"
	&a("行頭の１文字を削除します") (r!=1)? .
	(mb)? >A .
:A	&s mi[, mi=0, n=ln,
	#B o=ln, #B
	(n<o)? >C >B
:B	#11 (ct!=1)? #15 (ln!=o)? {#e >B} mi], #b &d.
:C	#11 (ct!=1)? #15 (ln!=o)? {#12 #x >C} mi], #b &d.

* P メニュー

1	"",34,3,20
	&81 &82 &83

;======== End of txf_vz16.def ========